home *** CD-ROM | disk | FTP | other *** search
/ Software Vault: The Gold Collection / Software Vault - The Gold Collection (American Databankers) (1993).ISO / cdr18 / mrun210.zip / MRUN210A.WAS < prev    next >
Text File  |  1993-04-28  |  23KB  |  701 lines
  1. ;MailRun v2.10:  Part A, Main body of script
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file serves as "home base" for the rest of the script.
  9. * All other scripts will return to this one if they are
  10. * exited normally.  It initializes MailRun, creates the
  11. * user interface, and then waits for action on the part of the
  12. * user.  If the user executes a mailrun, this section is also
  13. * responsible for taking care of scheduling.
  14. * 
  15. * Elements of the user interface are contained in the header
  16. * file (MRUN210.H).  Menu selections are fielded by parsemenu()
  17. * and the toolbar is controlled by parseobject().  The routines 
  18. * associated with menu items are contained in the header file 
  19. * immediately following parsemenu() and parseobject().  Some of
  20. * these in turn call routines in other script modules through 
  21. * the callscript() procedure.  Where necessary, a FLAG is set to
  22. * inform the target module which routines to execute.  
  23. * 
  24. * The code for the interface is #included in every module of 
  25. * MailRun so that any part of the script may be called from any 
  26. * other part.  Other script modules are called by MRUN210A and 
  27. * MRUN210G (the module responsible for executing the mailrun) 
  28. * using the "execute" command.  When a module is called from
  29. * MRUN210B-F, a "chain" command is used.
  30. * 
  31. **************************************************************************
  32. **************************************************************************
  33. #endcomment
  34.  
  35. #define MRUN210A
  36. #define MRUN210AG
  37. #define MRUN210AB
  38.  
  39. string MainBoxTabs
  40. integer RingInterrupt, AutoRun
  41. integer MailRunMenu, RunningMenu, FileMenu, ConfigMenu, AddMenu
  42. integer DefaultsMenu, ExecuteMenu, HelpMenu, EditMenu
  43.  
  44. #include "mrun210.h"
  45. #define HAVEYOUPAID;YOURFIFTEENDOLLARSYET
  46.  
  47. #comment
  48. *********************************************************************
  49. * 
  50. * MAIN()
  51. * 
  52. * Calls checkchild(), initialize(), maketasklist(),
  53. * makemailrunlist(), runmenu(), mrunmenu(), mrunwin(),
  54. * getfirstitem(), helpabout(), parsedialog(), parsekeystate(),
  55. * interfaceon(), executor(), makefullname()
  56. * 
  57. * Main first calls the initialization routines, then puts
  58. * up the main dialog box and waits for user action.
  59. * 
  60. *********************************************************************
  61. #endcomment
  62.  
  63. proc main
  64. string MRunIcons
  65.     checkchild()
  66.     initialize()
  67.     runmenu()
  68.     mrunmenu()
  69.     mrunwin()
  70.     makemailrunlist()
  71.     maketasklist()
  72.     getfirstitem()
  73.     showmenu MailRunMenu
  74.     if AutoRun == 1
  75.         filereset()
  76.         FLAGS |= RUNNING
  77.         GoWait = 1
  78.         PostRun = 3
  79.         pause 2
  80.     else
  81. #ifdef HAVEYOUPAID;YOURFIFTEENDOLLARSYET
  82.         helpabout()
  83. #else
  84.         mailrunbox()
  85. #endif
  86.     endif
  87.     interfaceon()
  88.     MRunIcons = makefullname(MailRunDir, "MRUNICON.DLL")
  89.     when dialog call parsedialog
  90.     while 1
  91.         if FLAGS & RUNNING
  92.             copyfile MRunIcons "C:\MRUNICON.DLL"
  93.             iconbutton 1 40 0 "" "C:\MRUNICON.DLL" 16 background
  94.             paint
  95.             delfile "C:\MRUNICON.DLL"
  96.              showmenu RunningMenu
  97.              executor()
  98.             copyfile MRunIcons "C:\MRUNICON.DLL"
  99.             iconbutton 1 40 0 "" "C:\MRUNICON.DLL" 0 background
  100.             paint
  101.             delfile "C:\MRUNICON.DLL"
  102.              showmenu MailRunMenu
  103.         endif
  104.     endwhile
  105. endproc
  106.  
  107.  
  108. #comment
  109. *********************************************************************
  110. * 
  111. * INITIALIZE()
  112. * 
  113. * Called by main()
  114. * 
  115. * Calls cleardir(), makemrn(), makefullname(), checkfile()
  116. * 
  117. * Saves system state and initializes global variables.
  118. * 
  119. *********************************************************************
  120. #endcomment
  121.  
  122. proc initialize
  123. string LastRun, env, temp , CleanupFile
  124. string StateCapPath, StateCapFile, StateDnldPath, StateUpldPath
  125. integer StateAutoDL, StateActionBar, StateMetaKeys
  126. integer blank = 0
  127.     ;Create the working directory
  128.     getenv "TEMP" env
  129.     if NULLSTR env
  130.         TempDir = makefullname($PWTASKPATH, "MRUNTEMP")
  131.     else
  132.         TempDir = makefullname(env, "MRUNTEMP")
  133.     endif
  134.     FLAGS = 0
  135.     MailRunIni = makefullname($WINPATH, "MAILRUN.INI")
  136.     profilerd MailRunIni "MailRun" "MailRun" MailRunTrunc
  137.     profilerd MailRunIni "MailRun" "MailRunDir" MailRunDir
  138.     profilerd MailRunIni "MailRun" "AutoRun" AutoRun
  139.  
  140.     ;Save the current state of PCPlus/Win
  141.     fetch autodnld StateAutoDL
  142.     fetch capture path StateCapPath
  143.     fetch capture file StateCapFile
  144.     fetch dnldpath StateDnldPath
  145.     fetch upldpath StateUpldPath
  146.     StateActionBar = $ACTIONBAR
  147.     StateMetaKeys = $METAKEYS
  148.     ;Save the system state in the cleanup file
  149.     cleanupfile = makefullname(TempDir, "CLEANUP.TMP")
  150.     profilewr CleanupFile "Cleanup" "StateAutoDL" StateAutoDL
  151.     profilewr CleanupFile "Cleanup" "StateCapPath" StateCapPath
  152.     profilewr CleanupFile "Cleanup" "StateCapFile" StateCapFile
  153.     profilewr CleanupFile "Cleanup" "StateDnldPath" StateDnldPath
  154.     profilewr CleanupFile "Cleanup" "StateUpldPath" StateupldPath
  155.     profilewr CleanupFile "Cleanup" "StateActionBar" StateActionBar
  156.     profilewr CleanupFile "Cleanup" "StateMetaKeys" StateMetaKeys
  157.  
  158.     ;Change the settings
  159.     set capture path MailRunDir
  160.     set capture query OFF
  161.     set autodnld OFF
  162.     set aspect rangechk OFF
  163.     metakeys OFF
  164.     actionbar OFF
  165.  
  166.     ;If the mailrun in MAILRUN.INI doesn't exist, create it
  167.     if NULLSTR MailRunTrunc
  168.         blank = 1
  169.     else
  170.         LastRun = makefullname(MailRunDir, MailRunTrunc)
  171.     endif
  172.     if !(checkfile(LastRun)) || blank
  173.         temp = makefullname(MailRunDir, "*.MRN")
  174.         findfirst temp
  175.         if FOUND
  176.             MailRunTrunc = $FILENAME
  177.             LastRun = makefullname(MailRunDir, MailRunTrunc)
  178.         else
  179.             MailRunTrunc = "mailrun.mrn"
  180.             MailRunList = "mailrun.mrn"
  181.             makemrn()
  182.             LastRun = MailRun
  183.         endif
  184.     endif
  185.     ;Copy the mailrun to the temp directory
  186.     MailRun = makefullname(TempDir, MailRunTrunc)
  187.     TaskList = makefullname(TempDir, "TASKLIST.TMP")
  188.     copyfile LastRun MailRun
  189.     profilerd MailRun "MailRun" "Archiver" Archiver
  190.     profilerd MailRun "MailRun" "QWKReader" QWKReader
  191.     profilerd MailRun "MailRun" "LogViewer" LogViewer
  192. endproc
  193.  
  194.  
  195. #comment
  196. *********************************************************************
  197. * 
  198. * EXECUTOR()
  199. * 
  200. * Called by main()
  201. * 
  202. * Calls schedulebox(), mailrunbox(), checktime(), fileexit(),
  203. * scheduler(), domailrun(), makefullname(), filereset(),
  204. * maketasklist()
  205. * 
  206. * Executes MRUN210G
  207. * 
  208. * Puts up the MailRun Scheduling box and parses the result.
  209. * 
  210. *********************************************************************
  211. #endcomment
  212.  
  213. proc executor
  214. string HH, MM, SS, temp, LogFile, domailrun
  215. integer Hour, Minute, Second
  216. integer dialogstatus, boxstatus
  217.     domailrun = makefullname(MailRunDir, "MRUN210G")
  218.     findfirst MailRun
  219.     LogFile = $FNAME
  220.     strcat LogFile ".CAP"
  221.     if AppendLog == 0
  222.         ;if user does not want to append to existing log file
  223.         temp = makefullname(MailRunDir, LogFile)
  224.         delfile temp
  225.     endif
  226.     set capture file LogFile
  227.     profilerd MailRun "MailRun" "RingInterrupt" RingInterrupt
  228.     if AutoRun == 0
  229.         profilerd MailRun "MailRun" "ExecTime" ExecTime
  230.         profilerd MailRun "MailRun" "PostRun" PostRun
  231.         profilerd MailRun "MailRun" "GoWait" GoWait
  232.         schedulebox()
  233.         if GoWait == 1 
  234.             disable CTRL 230
  235.         endif
  236.     endif
  237.     ;boxstatus indicates whether or not mailrunbox is showing
  238.     boxstatus = 0
  239.     ;turn off parsedialog() for parsing contols
  240.     clearwhen dialog
  241.     while (FLAGS & RUNNING) && (AutoRun == 0)
  242.         dialogstatus = $DIALOG
  243.         switch dialogstatus
  244.             case 1
  245.                 ;User selected "Cancel"
  246.                 FLAGS &= IDLE
  247.                 mailrunbox()
  248.                 boxstatus = 1
  249.                 ;turn back on parsedialog() for parsing controls
  250.                 when dialog call parsedialog
  251.                 return
  252.             endcase
  253.             case 10
  254.                 ;User selected "OK"
  255.                 if GoWait == 2
  256.                     ;if the scheduler is turned on...
  257.                     ;parse the entered time
  258.                     strextract HH ExecTime ":" 0
  259.                     strextract MM ExecTime ":" 1
  260.                     strextract SS ExecTime ":" 2
  261.                     Hour = checktime(HH)
  262.                     Minute = checktime(MM)
  263.                     Second = checktime(SS)
  264.                     if ((Hour < 0) || (Hour > 23)) || ((Minute < 0) || \
  265.                         (Minute > 59)) || ((Second < 0) || (Second > 59))
  266.                         usermsg "The time must be in 24 hour format!"
  267.                         ExecTime = "HH:MM:SS"
  268.                         updatedlg 128
  269.                         dialogstatus = $DIALOG
  270.                         loopwhile
  271.                     endif
  272.                     profilewr MailRun "MailRun" "ExecTime" ExecTime
  273.                 endif
  274.                 profilewr MailRun "MailRun" "RingInterrupt" RingInterrupt
  275.                 profilewr MailRun "MailRun" "PostRun" PostRun
  276.                 profilewr MailRun "MailRun" "GoWait" GoWait
  277.                 exitwhile
  278.             endcase
  279.             case 50
  280.                 ;User changed Now/Later status
  281.                 if GoWait == 2
  282.                     enable CTRL 230
  283.                 else
  284.                     disable CTRL 230
  285.                 endif
  286.             endcase
  287.         endswitch
  288.     endwhile
  289.     while FLAGS & RUNNING
  290.         if AutoRun == 1
  291.             profilewr MailRunIni "MailRun" "AutoRun" 0
  292.         endif
  293.         if GoWait == 2
  294.             ;if user has scheduled for a later time...
  295.             mailrunbox()
  296.             boxstatus = 1
  297.             disable CTRL 170
  298.             when dialog call parsedialog
  299.             scheduler()
  300.         endif
  301.         if FLAGS & RUNNING
  302.             ;if the user has not terminated the mailrun, execute it
  303.             execute domailrun
  304.             boxstatus = 0
  305.             if PostRun == 2
  306.                 ;if post-mailrun activity is "Restart", reset the mailrun
  307.                 filereset()
  308.             elseif PostRun == 3
  309.                 ;if post-mailrun activity is "Shut Down", do so
  310.                 fileexit()
  311.             else
  312.                 ;if post-mailrun activity is "Remain Idle", reset RUNNING flag
  313.                 FLAGS &= IDLE
  314.             endif
  315.         endif
  316.     endwhile
  317.     if boxstatus == 0
  318.         ;if mailrunbox is not displayed, show it
  319.         mailrunbox()
  320.         when dialog call parsedialog
  321.     endif
  322.     if GoWait == 2
  323.         ;if the scheduler was used, enable the combobox
  324.         enable CTRL 170
  325.     endif
  326.     statmsg ""
  327.     maketasklist()
  328.     updatedlg 80
  329. endproc
  330.  
  331.  
  332. #comment
  333. *********************************************************************
  334. * 
  335. * SCHEDULER()
  336. * 
  337. * Called by executor()
  338. * 
  339. * Waits until the scheduled time before executing the
  340. * mailrun.
  341. * 
  342. *********************************************************************
  343. #endcomment
  344.  
  345. proc scheduler
  346. long LExecTime
  347.     updatedlg 64
  348.     ;get the system time for execution
  349.     strsltime $DATE ExecTime LExecTime
  350.     if LExecTime <= $LTIME
  351.         ;if the time of execution is earlier than the current time
  352.         ;increment the time of execution by 24 hours.
  353.         LExecTime += 86400
  354.     endif
  355.     strupr MailRunTrunc
  356.     while (LExecTime > $LTIME) && (FLAGS & RUNNING)
  357.         ;wait until the designated time is reached
  358.         statmsg "%s will execute at %s       Current time is %s" \
  359.             MailRunTrunc ExecTime $TIME24
  360.         pause 1
  361.     endwhile
  362.     strlwr MailRunTrunc
  363. endproc
  364.  
  365.  
  366. #comment
  367. *********************************************************************
  368. * 
  369. * CHECKTIME()
  370. * 
  371. * Called by executor()
  372. * 
  373. * Converts a string into an integer time value.  Returns
  374. * a value of 60 if a non-numeric character is received.
  375. * 
  376. *********************************************************************
  377. #endcomment
  378.  
  379. func checktime : integer
  380. strparm TimeString
  381. integer TimeInteger
  382.     atoi TimeString TimeInteger
  383.     if TimeInteger == 0
  384.         if not strcmpi TimeString "00"
  385.             TimeInteger = 60
  386.         endif
  387.     endif
  388.     return TimeInteger
  389. endfunc
  390.  
  391.  
  392. #comment
  393. *********************************************************************
  394. * 
  395. * MRUNMENU()
  396. * 
  397. * Called by main()
  398. * 
  399. * Creates the MailRun menu bar.
  400. * 
  401. *********************************************************************
  402. #endcomment
  403.  
  404. proc mrunmenu
  405.     menubar MailRunMenu
  406.         menupopup MailRunMenu "&File" FileMenu
  407.             menuitem FileMenu 1 "&New"
  408.             menuitem FileMenu 2 "&Save"
  409.             menuitem FileMenu 3 "Save &As"
  410.             menuitem FileMenu SEPARATOR
  411.             menuitem FileMenu 4 "&Reset mailrun"
  412.             menuitem FileMenu 5 "&Delete mailrun"
  413.             menuitem FileMenu SEPARATOR
  414.             menuitem FileMenu 6 "&Create AutoRun"
  415.             menuitem FileMenu SEPARATOR
  416.             menuitem FileMenu 7 "E&xit"
  417.         menupopup MailRunMenu "&Edit" EditMenu
  418.             menuitem EditMenu 8 "Cu&t"
  419.             menuitem EditMenu 9 "&Copy"
  420.             menuitem EditMenu 10 "&Paste"
  421.             menuitem EditMenu SEPARATOR
  422.             menuitem EditMenu 11 "De&lete"
  423.         menupopup MailRunMenu "&Configure" ConfigMenu
  424.             menuitem ConfigMenu 12 "&Mailrun Settings"
  425.             menuitem ConfigMenu 13 "&BBS Settings"
  426.             menuitem ConfigMenu 14 "BBS &Prompts"
  427.             menuitem ConfigMenu 15 "BBS Mail &Door"
  428.             menupopup ConfigMenu "De&faults" DefaultsMenu
  429.                 menuitem DefaultsMenu 16 "&MailRun"
  430.                 menuitem DefaultsMenu 17 "&BBS"
  431.                 menuitem DefaultsMenu 18 "&Prompts"
  432.                 menuitem DefaultsMenu 19 "Mail &Door"
  433.         menupopup MailRunMenu "&Add" AddMenu
  434.             menuitem AddMenu 20 "&New BBS"
  435.             menuitem AddMenu 21 "&Get/Send Mail"
  436.             menuitem AddMenu 22 "&Upload File"
  437.             menuitem AddMenu 23 "&Download File"
  438.             menuitem AddMenu 24 "Send &Command"
  439.             menuitem AddMenu 25 "Execute &Script"
  440.         menupopup MailRunMenu "&Execute" ExecuteMenu
  441.             menuitem ExecuteMenu 26 "&Execute MailRun"
  442.              menuitem ExecuteMenu 27 "&QWK Reader"
  443.             menuitem ExecuteMenu 28 "&Archiver"
  444.             menuitem ExecuteMenu 29 "&View Log File"
  445.         menupopup MailRunMenu "&Help" HelpMenu
  446.             menuitem HelpMenu 30 "&Contents"
  447.             menuitem HelpMenu 31 "&On current window..."
  448.             menuitem HelpMenu SEPARATOR
  449.             menuitem HelpMenu 32 "&About MailRun"
  450. endproc
  451.  
  452.  
  453. #comment
  454. *********************************************************************
  455. * 
  456. * RUNMENU()
  457. * 
  458. * Called by main()
  459. * 
  460. * Creates the menu bar used while a mailrun is executing.
  461. * 
  462. *********************************************************************
  463. #endcomment
  464.  
  465. proc runmenu
  466.     menubar RunningMenu
  467.         menupopup RunningMenu "&File" FileMenu
  468.             menuitem FileMenu 1 "&New"
  469.             menuitem FileMenu 2 "&Save"
  470.             menuitem FileMenu 3 "Save &As"
  471.             menuitem FileMenu SEPARATOR
  472.             menuitem FileMenu 4 "&Reset mailrun"
  473.             menuitem FileMenu 5 "&Delete mailrun"
  474.             menuitem FileMenu SEPARATOR
  475.             menuitem FileMenu 6 "&Create AutoRun"
  476.             menuitem FileMenu SEPARATOR
  477.             menuitem FileMenu 7 "E&xit"
  478.         menupopup RunningMenu "&Edit" EditMenu
  479.             menuitem EditMenu 8 "Cu&t"
  480.             menuitem EditMenu 9 "&Copy"
  481.             menuitem EditMenu 10 "&Paste"
  482.             menuitem EditMenu SEPARATOR
  483.             menuitem EditMenu 11 "De&lete"
  484.         menupopup RunningMenu "&Configure" ConfigMenu
  485.             menuitem ConfigMenu 12 "&Mailrun Settings"
  486.             menuitem ConfigMenu 13 "&BBS Settings"
  487.             menuitem ConfigMenu 14 "BBS &Prompts"
  488.             menuitem ConfigMenu 15 "BBS Mail &Door"
  489.             menupopup ConfigMenu "De&faults" DefaultsMenu
  490.                 menuitem DefaultsMenu 16 "&MailRun"
  491.                 menuitem DefaultsMenu 17 "&BBS"
  492.                 menuitem DefaultsMenu 18 "&Prompts"
  493.                 menuitem DefaultsMenu 19 "Mail &Door"
  494.         menupopup RunningMenu "&Add" AddMenu
  495.             menuitem AddMenu 20 "&New BBS"
  496.             menuitem AddMenu 21 "&Get/Send Mail"
  497.             menuitem AddMenu 22 "&Upload File"
  498.             menuitem AddMenu 23 "&Download File"
  499.             menuitem AddMenu 24 "Send &Command"
  500.             menuitem AddMenu 25 "Execute &Script"
  501.         menupopup RunningMenu "&Execute" ExecuteMenu
  502.             menuitem ExecuteMenu 26 "T&erminate MailRun"
  503.              menuitem ExecuteMenu 27 "&QWK Reader"
  504.             menuitem ExecuteMenu 28 "&Archiver"
  505.             menuitem ExecuteMenu 29 "&View Log File"
  506.         menupopup RunningMenu "&Help" HelpMenu
  507.             menuitem HelpMenu 30 "&Contents"
  508.             menuitem HelpMenu 31 "&On current window..."
  509.             menuitem HelpMenu SEPARATOR
  510.             menuitem HelpMenu 32 "&About MailRun"
  511. endproc
  512.  
  513.  
  514. #comment
  515. *********************************************************************
  516. * 
  517. * MRUNWIN()
  518. * 
  519. * Called by main()
  520. * 
  521. * Calls makefullname()
  522. * 
  523. * Creates the MailRun icon bar.  The DLL containing the
  524. * icons is copied to the C: root directory because the
  525. * iconbutton function will not accept variables as file
  526. * names.  C:\ is used because it is fairly certain to exist.
  527. * 
  528. *********************************************************************
  529. #endcomment
  530.  
  531. proc mrunwin
  532. string MRunIcons
  533.     MRunIcons = makefullname(MailRunDir, "MRUNICON.DLL")
  534.     copyfile MRunIcons "C:\MRUNICON.DLL"
  535.     defuserwin TOP PIXELS 34 192 192 192 bitmap
  536.         switch $XPIXELS
  537.             case 1280
  538.                 iconbutton  1   25 0 "" "C:\MRUNICON.DLL"  0 userwin
  539.                 iconbutton  2  300 0 "" "C:\MRUNICON.DLL"  1 userwin
  540.                 iconbutton  3  575 0 "" "C:\MRUNICON.DLL"  2 userwin 
  541.                 iconbutton  4  850 0 "" "C:\MRUNICON.DLL"  3 userwin 
  542.                 iconbutton  5 1250 0 "" "C:\MRUNICON.DLL"  4 userwin
  543.                 iconbutton  6 1525 0 "" "C:\MRUNICON.DLL"  5 userwin
  544.                 iconbutton  7 1800 0 "" "C:\MRUNICON.DLL"  6 userwin
  545.                 iconbutton  8 2075 0 "" "C:\MRUNICON.DLL"  7 userwin
  546.                 iconbutton  9 2350 0 "" "C:\MRUNICON.DLL"  8 userwin 
  547.                 iconbutton 10 2625 0 "" "C:\MRUNICON.DLL"  9 userwin
  548.                 iconbutton 11 2900 0 "" "C:\MRUNICON.DLL" 10 userwin
  549.                 iconbutton 12 3300 0 "" "C:\MRUNICON.DLL" 11 userwin
  550.                 iconbutton 13 3575 0 "" "C:\MRUNICON.DLL" 12 userwin
  551.                 iconbutton 14 3850 0 "" "C:\MRUNICON.DLL" 13 userwin
  552.                 iconbutton 15 4250 0 "" "C:\MRUNICON.DLL" 14 userwin
  553.                 iconbutton 16 4650 0 "" "C:\MRUNICON.DLL" 15 userwin
  554.             endcase
  555.             case 1024
  556.                 iconbutton  1   30 0 "" "C:\MRUNICON.DLL"  0 userwin
  557.                 iconbutton  2  374 0 "" "C:\MRUNICON.DLL"  1 userwin
  558.                 iconbutton  3  718 0 "" "C:\MRUNICON.DLL"  2 userwin 
  559.                 iconbutton  4 1062 0 "" "C:\MRUNICON.DLL"  3 userwin 
  560.                 iconbutton  5 1562 0 "" "C:\MRUNICON.DLL"  4 userwin
  561.                 iconbutton  6 1906 0 "" "C:\MRUNICON.DLL"  5 userwin
  562.                 iconbutton  7 2250 0 "" "C:\MRUNICON.DLL"  6 userwin
  563.                 iconbutton  8 2594 0 "" "C:\MRUNICON.DLL"  7 userwin
  564.                 iconbutton  9 2938 0 "" "C:\MRUNICON.DLL"  8 userwin 
  565.                 iconbutton 10 3282 0 "" "C:\MRUNICON.DLL"  9 userwin
  566.                 iconbutton 11 3626 0 "" "C:\MRUNICON.DLL" 10 userwin
  567.                 iconbutton 12 4126 0 "" "C:\MRUNICON.DLL" 11 userwin
  568.                 iconbutton 13 4470 0 "" "C:\MRUNICON.DLL" 12 userwin
  569.                 iconbutton 14 4814 0 "" "C:\MRUNICON.DLL" 13 userwin
  570.                 iconbutton 15 5314 0 "" "C:\MRUNICON.DLL" 14 userwin
  571.                 iconbutton 16 5814 0 "" "C:\MRUNICON.DLL" 15 userwin
  572.             endcase
  573.             case 800
  574.                 iconbutton  1   40 0 "" "C:\MRUNICON.DLL"  0 userwin
  575.                 iconbutton  2  480 0 "" "C:\MRUNICON.DLL"  1 userwin
  576.                 iconbutton  3  920 0 "" "C:\MRUNICON.DLL"  2 userwin 
  577.                 iconbutton  4 1360 0 "" "C:\MRUNICON.DLL"  3 userwin
  578.                 iconbutton  5 2000 0 "" "C:\MRUNICON.DLL"  4 userwin
  579.                 iconbutton  6 2440 0 "" "C:\MRUNICON.DLL"  5 userwin
  580.                 iconbutton  7 2880 0 "" "C:\MRUNICON.DLL"  6 userwin
  581.                 iconbutton  8 3320 0 "" "C:\MRUNICON.DLL"  7 userwin
  582.                 iconbutton  9 3760 0 "" "C:\MRUNICON.DLL"  8 userwin 
  583.                 iconbutton 10 4200 0 "" "C:\MRUNICON.DLL"  9 userwin
  584.                 iconbutton 11 4640 0 "" "C:\MRUNICON.DLL" 10 userwin
  585.                 iconbutton 12 5280 0 "" "C:\MRUNICON.DLL" 11 userwin 
  586.                 iconbutton 13 5720 0 "" "C:\MRUNICON.DLL" 12 userwin 
  587.                 iconbutton 14 6160 0 "" "C:\MRUNICON.DLL" 13 userwin 
  588.                 iconbutton 15 6800 0 "" "C:\MRUNICON.DLL" 14 userwin 
  589.                 iconbutton 16 7440 0 "" "C:\MRUNICON.DLL" 15 userwin 
  590.             endcase
  591.             default
  592.                 iconbutton  1   50 0 "" "C:\MRUNICON.DLL"  0 userwin
  593.                 iconbutton  2  600 0 "" "C:\MRUNICON.DLL"  1 userwin
  594.                 iconbutton  3 1150 0 "" "C:\MRUNICON.DLL"  2 userwin
  595.                 iconbutton  4 1700 0 "" "C:\MRUNICON.DLL"  3 userwin
  596.                 iconbutton  5 2500 0 "" "C:\MRUNICON.DLL"  4 userwin
  597.                 iconbutton  6 3050 0 "" "C:\MRUNICON.DLL"  5 userwin 
  598.                 iconbutton  7 3600 0 "" "C:\MRUNICON.DLL"  6 userwin 
  599.                 iconbutton  8 4150 0 "" "C:\MRUNICON.DLL"  7 userwin 
  600.                 iconbutton  9 4700 0 "" "C:\MRUNICON.DLL"  8 userwin 
  601.                 iconbutton 10 5250 0 "" "C:\MRUNICON.DLL"  9 userwin
  602.                 iconbutton 11 5800 0 "" "C:\MRUNICON.DLL" 10 userwin
  603.                 iconbutton 12 6600 0 "" "C:\MRUNICON.DLL" 11 userwin 
  604.                 iconbutton 13 7150 0 "" "C:\MRUNICON.DLL" 12 userwin
  605.                 iconbutton 14 7700 0 "" "C:\MRUNICON.DLL" 13 userwin 
  606.                 iconbutton 15 8500 0 "" "C:\MRUNICON.DLL" 14 userwin 
  607.                 iconbutton 16 9300 0 "" "C:\MRUNICON.DLL" 15 userwin
  608.             endcase
  609.         endswitch
  610.     paint
  611.     delfile "C:\MRUNICON.DLL"
  612. endproc
  613.  
  614.  
  615. #comment
  616. *********************************************************************
  617. * 
  618. * MAILRUNBOX()
  619. * 
  620. * Called by main(), parsedialog(), callscript(), executor(),
  621. * sendscript()
  622. * 
  623. * Draws the main MailRun dialog box.
  624. * 
  625. *********************************************************************
  626. #endcomment
  627.  
  628. proc mailrunbox
  629. destroydlg
  630. MainBoxTabs = "20,30,220,230,233,236,239,242"
  631. AttemptNum = "0"
  632. HelpPage = 1
  633. dialogbox 8 36 346 181 15 "MailRun" HELPID HelpPage
  634.    groupbox 10 33 228 135 "Task List" shadow
  635.    flistbox 15 52 218 102 TaskList MainBoxTabs single TaskItem
  636.    text  15 153 49 8 left "# = permanent"
  637.    text  76 153 49 8 left "ñ = temporary"
  638.    text  140 153 33 8 left "! = error"
  639.    text  182 153 53 8 left "@ = completed"
  640.    groupbox 244 33 90 135 "Statistics" shadow
  641.    text  248 55 62 8 right "BBSs in mailrun:"
  642.    text  248 69 62 8 right "BBSs completed:"
  643.    text  248 83 62 8 right "BBSs left to call:"
  644.    text  248 97 62 8 right "Items in mailrun:"
  645.    text  248 111 62 8 right "Items completed:"
  646.    text  248 125 62 8 right "Item errors:"
  647.    text  248 139 62 8 right "Items remaining:"
  648.    text  248 153 62 8 right "Dialing Attempt:"
  649.    vtext 314 55 16 9 left BBSTotal
  650.    vtext 314 69 16 9 left BBSComplete
  651.    vtext 314 83 16 9 left BBSRemaining
  652.    vtext 314 97 16 9 left ItemTotal
  653.    vtext 314 111 16 9 left ItemComplete
  654.    vtext 314 125 16 9 left ItemError
  655.    vtext 314 139 16 9 left ItemRemaining
  656.    vtext 314 153 16 9 left AttemptNum
  657.    text  102 14 74 8 right "The current mailrun is:"
  658.    combobox 180 12 76 41 MailRunList MailRunTrunc sort
  659.    pushbutton 0 0 0 0 "          &t" normal default
  660.    pushbutton 0 0 0 0 "          &u" normal
  661.    pushbutton 0 0 0 0 "          &i" normal
  662. enddialog
  663. if FLAGS & RUNNING
  664.     disable CTRL 170
  665. endif
  666. endproc
  667.  
  668.  
  669. #comment
  670. *********************************************************************
  671. * 
  672. * SCHEDULEBOX()
  673. * 
  674. * Called by executor()
  675. * 
  676. * Draws the MailRun Scheduler dialog box.
  677. * 
  678. *********************************************************************
  679. #endcomment
  680.  
  681. proc schedulebox
  682. destroydlg
  683. HelpPage = 3
  684. dialogbox 55 58 238 120 15 "MailRun Scheduler" HELPID HelpPage
  685.    groupbox 10 14 122 67 "Schedule" shadow
  686.    radiobutton 21 28 90 10 "Execute MailRun Now!" GoWait
  687.    radiobutton 21 44 90 10 "Execute MailRun Later..." endgroup
  688.    text  17 62 43 8 right "Execute At:"
  689.    editbox 64 60 55 12 ExecTime 8
  690.    groupbox 142 14 80 67 "When finished... " shadow
  691.    radiobutton 152 28 60 10 "Remain Idle" PostRun
  692.    radiobutton 152 44 60 10 "Restart" 
  693.    radiobutton 152 60 60 10 "Shut Down" endgroup
  694.    checkbox 10 92 116 12 "Interrupt mailrun if phone rings" RingInterrupt
  695.    pushbutton 132 93 40 14 "&OK" normal default
  696.    pushbutton 182 93 40 14 "&Cancel" cancel
  697. enddialog
  698. endproc
  699.  
  700.  
  701.